[Tustep-Liste] Begriffsregister

[Kuno Schaelkle]

Sehr geehrter Herr Notz,

-----------------------------------------------------
> <re>êwangeli</re>	<rf><r>4,3</r>	<r>375,3</r></rf>
> <re>geist</re>		<rf><r>422,1</r></rf>
> <re>heilig</re>		<rf><r>50,3</r>	<r>263,6</r></rf>
>
> Diese Liste möchte ich nun in folgende überführen, damit ich sie  
> schlussendlich sortieren und zur Korrektur verwenden kann:
>
> <r>4,3</r>	<re>êwangeli</re>
> <r>50,3</r>	<re>heilig</re>
> <r>263,6</r>	<re>heilig</re>
> <r>375,3</r>	<re>êwangeli</re>
> <r>422,1</r>	<re>geist</re>
-------------------------------------------------------

das folgende Makro sollte diese Aufgabe erledigen.

Mit freundlichen Grüßen
Kuno Schälkle

---------------------------------------------------------

$$! quelle, ziel
$$-
$$ MODE TUSCRIPT

SET status = CHECK (quelle, READ, TUSTEP)
ERROR/STOP "QUELLE: ", status

SET status = CHECK (ziel, WRITE, TUSTEP)
ERROR/STOP "ZIEL: ", status

SET status = UNIQUE (quelle, ziel)
ERROR/STOP "Datei ", status, " ist mehrfach angegeben"

COMPILE

ACCESS q: READ/RECORDS "{quelle}" sn.zn/un, zeile

SET zeilen = *
LOOP/999999
    READ/IGNORE/EXIT q
    SET text = EXTRACT (zeile, |":<<re>>:", ":<</re>>:"|)
    SET refs = EXTRACT (zeile, ":<<rf>>:"|, |":<</rf>>:")
    SET refs = EXCHANGE (refs, ":<> :':")
    LOOP ref = refs
       SET zeile  = CONCAT (ref, " ", text)
       SET zeilen = APPEND (zeilen, zeile)
    ENDLOOP
ENDLOOP

ENDACCESS/PRINT q

SET zeilen = MIXED_SORT (zeilen)

FILE/ERASE/PRINT "{ziel}" = zeilen

ENDCOMPILE