[Tustep-Liste] Datei mit P-Tag erzeugen

[Thomas Kollatz]

Liebe Liste, liebe Alten, liebe Jungen, 

auch wenn ausdrücklich nach einer Old School Lösung gefragt wurde, geht das natürlich auch ohne Sprünge und New School und könnte etwa so aussehen. Geht sicher noch eleganter, aber so ist es vermutlich am verständlichsten. 
Wenn eine Leerzeile eingelesen wird, wird nicht geschrieben (CYCLE), dafür eine Variable (p_vor_zeile)  mit dem <p>-Tag belegt, 
sonst wird geschrieben (WRITE)  und die Variable mit dem Tag mit dem Inhalt der Zeile verbunden (concat), nach dem Schreiben wird diese Variable wieder geleert. 

Herzliche Grüße
Thomas Kollatz
——> 

$$ MODE TUSCRIPT,{}
quelle="a", ziel="b"

ERROR/STOP CREATE (quelle,seq-e,-std-)
ERROR/STOP CREATE (ziel,seq-e,-std-)

MODE DATA
$$ daten=*
zeile1
zeile2

zeile3
zeile4
zeile5

zeile6
zeile7
$$ MODE TUSCRIPT

FILE/ERASE $quelle =daten

p_vor_zeile=""
ACCESS q: READ/RECORDS  $quelle s.z/u,zeile
ACCESS z: WRITE/RECORDS $ziel   s.z/u,zeile
LOOP
 READ/NEXT/EXIT q
 IF (zeile=="") THEN
  p_vor_zeile="<p>"
  CYCLE
 ELSE
  zeile=CONCAT (p_vor_zeile,zeile)
  WRITE z
  p_vor_zeile=""
 ENDIF
ENDLOOP
ENDACCESS/PRINT q
ENDACCESS/PRINT z