[Tustep-Liste] Automatische Abfragen im Katalog der DNB

[Thomas Kollatz]

Sehr geehrter Herr Luckscheiter, 

ich habe seit ein paar Jahren eine Routine zur Abfrage von GND-IDs im Einsatz, wobei ich den DARIAH Normdatendienst und den Entityfacts-Dienst der DNB nutze, der die d-nb.info/gnd/<IDN> Infos enthält und dies weiteren Normdaten und Querverweisen angereichert ausgibt. 

Ich kopiere die für ihren Fall angepasste Routine in die Mail. Auch wenn das bei d’Agar nicht der Fall ist, kann so eine GND-Anfrage mehrere IDS ergeben, die zu prüfen sind, darum sammele ich den „output“ in einer Sternvariable, hier das Skript: 
Wenn sie die auskommentierten TRACE-Funktion aktivieren, sehen sie was Schritt für Schritt passiert.  In der Variable gndinfo befindet sich das Ergebnis (bzw.) die Ergebnisse der Anfrage nach „Jacques d’Agar“. 

Herzliche Grüße
Thomas Kollatz

$$ MODE TUSCRIPT,{}
--- Suche bei DARIAH-DE Normdatendienst GND
--- INFO: https://wiki.de.dariah.eu/display/publicde/DARIAH-DE+Normdatendienste
url="http://ref.dariah.eu/beta/pndsearch/pndquery.xql"
query=*
DATA ln=Jacques d'Agar
query=ENCODE(query,cgi)
daten=REQUEST(url,query)
-TRACE *daten
gndids=*
ACCESS q: READ/STREAM/VARIABLE/UTF8 $daten s,a+t+e,typ,stack
LOOP
READ/EXIT q
IF (stack.ew."<link>") THEN
-TRACE *stack,t
target=GET_ATTRIBUTE (t,"target")
-TRACE *target
gndid=EXTRACT (target,":*gnd/:"|,0)
-TRACE *gndid
gndids=APPEND(gndids,gndid)
ENDIF
ENDLOOP
ENDACCESS q
--- Abfrage bei ENTITY-Facts s. http://www.dnb.de/DE/Service/DigitaleDienste/EntityFacts/entityfacts_node.html
gndinfo=*
LOOP gndid=gndids
 --url=CONCAT ("http://d-nb.info/gnd/",gndentry,"/about/html")
 url=CONCAT ("http://hub.culturegraph.org/entityfacts/",gndid)
--TRACE *url
 daten=REQUEST(url)
--TRACE *daten
 rdfxml=DECODE(daten,utf8)
 gndinfo=APPEND(gndinfo,rdfxml)
ENDLOOP
TRACE *gndinfo



Thomas Kollatz
http://orcid.org/0000-0003-1904-1841



> Am 24.05.2018 um 16:54 schrieb Stefan Luckscheiter <luckscheiter at bbaw.de>:
> 
> Diskussionsforum Tustep-Liste
> Weitere Informationen: www.itug.de
> ------------------------------------------------------------
> 
> Liebe Listen-Leser,
> 
> Ich würde gerne mit Hilfe von REQUEST auf die Normdaten zu Personen im Katalog der DNB zugreifen, um schlußendlich die GND-Nummern zu Personen, von denen ich Namen und Sterbedatum kenne, automatisch abzurufen.
> 
> Auf folgende Weise habe ich versucht, den Eintrag zu Jacques d'Agar gest. 1715 (http://d-nb.info/gnd/1026902215) aufzurufen:
> 
> 
> SECTION abruf
> 
>   SET ind = *
>   DATA term=Agar 1715
>   SET frag = ENCODE (ind,CGI)
>   SET adresse = "https://portal.dnb.de/opac.htm"
>   SET antw = REQUEST (adresse,frag)
>   SET antw = DECODE (antw, UTF8)
> 
> ENDSECTION
> 
> Aber obwohl die beiden Angaben (Agar und 1715) ausreichen, um mit der Suchmaske auf https://portal.dnb.de/opac.htm zu dem gewünschten Datensatz zu gelangen, liefert die Seite nicht das gewünschte Ergebnis. Kann mir jemand sagen, was ich hier falsch mache?
> 
> Mit besten Grüßen,
> 
> Stefan Luckscheiter
> 
> 
> ***********************************************
> Leibniz-Edition Potsdam
> der Berlin-Brandenburgischen Akademie der Wissenschaften
> Am Neuen Markt 8
> 14467 Potsdam
> 
> Telefon: +49 (0)331 2796 121
> Fax: +49 (0)331 2796 130
> http://www.bbaw.de/bbaw/Forschung/Forschungsprojekte/leibniz_potsdam/de/Startseite
> 
> ------------------------------------------------------------
> Tustep-Liste at itug.de
> https://lists.uni-wuerzburg.de/mailman/listinfo/tustep-liste

-------------- nächster Teil --------------
Ein Dateianhang mit HTML-Daten wurde abgetrennt...
URL: <https://lists.itug.de/pipermail/tustep-liste/attachments/20180524/f61b4d80/attachment.htm>